Fonction de restriction de couple

Comme avec la fonction de détection de collision, la fonction de restriction de couple peut réduire les dommages lors d'une collision.

Fonction de détection de collision (Fonction de détection d'erreur de mouvement du robot)

La valeur de restriction de couple utilisée pour cette fonction est définie en ajoutant la marge à la valeur de couple limite supérieure utilisée dans le programme afin d'éviter tout dysfonctionnement. En utilisant la fonction de restriction de couple, la force de pression peut être réduite.

Par exemple, si le couple est limité à 30 %, la force de pression peut également être réduite à 30 %. De plus, le robot s'arrête immédiatement lorsque le couple atteint la valeur limite supérieure. En arrêtant immédiatement le robot, un effet de réduction supplémentaire de 20 à 30 % peut être obtenu.

Lorsque le couple est limité à 30 % et que le robot est immédiatement arrêté, un total inférieur à 25 % ou un effet de réduction équivalent peut être obtenu.

Pour les robots SCARA, l'extrémité de l'arbre prolongé peut se coincer et se plier. Pour réduire l'occurrence de l'arbre tordu, il est recommandé d'utiliser cette fonction pour réduire la force de pression au degré maximum.

En cas de dysfonctionnement, prenez l'une des mesures suivantes pour l'axe de dysfonctionnement.

• Désactivez LimitTorqueStop ou LimitTorqueStopLp
• Augmentez la valeur seuil de LimitTorque ou de LimitTorqueLp

Pour utiliser la fonction de restriction de couple pour le mouvement de déplacement, suivez les étapes ci-dessous.

1. Exécutez PTCLR et démarrez la mesure de couple.
2. Exécutez le mouvement de déplacement.
3. Mesurez la valeur de couple maximale par PTRQ, puis ajoutez-y la marge.
4. Définissez LimitTorqeLP et LimitTorqeLPStop.

Si le robot est temporairement arrêté dans le mouvement à faible puissance, une valeur supérieure au fonctionnement normal du programme ou au mouvement de déplacement peut être obtenue. Dans ce cas, exécutez l'arrêt temporaire tout en mesurant PTRQ et incluez-le dans la mesure.

Pour plus de détails sur la commande et la fonction, reportez-vous au manuel suivant.

"Référence du langage SPEL+"

• Instruction LimitTorque, fonction LimitTorque
• Instruction LimitTorqueLP, fonction LimitTorqueLP
• Instruction LimitTorqueStop, fonction LimitTorqueStop
• Instruction LimitTorqueStopLP, fonction LimitTorqueStopLP

Ce qui suit est un exemple de programme qui configure automatiquement la fonction de détection de collision et la fonction de restriction de couple.

Le programme répète le mouvement appelé "all_ax_move".

Le programme active la fonction de détection de collision, mesure le couple maximal dans les cinq premiers mouvements, ajoute la marge à la valeur mesurée (1,2 fois si HighPower, 1,4 fois si LowPower) et définit la valeur de couple limite supérieure pour arrêter le robot au couple limite supérieur.

Ceci est un exemple de réglage automatique pour répéter le mouvement avec les réglages ci-dessus à partir de la sixième fois.

Lorsque la valeur de couple limite supérieure est modifiée, la valeur modifiée est considérée comme étant "1,0" pour la mesure PTRQ suivante. Si la marge de 1,2 fois est définie, PTRQ est légèrement supérieur à 0,8, et si la marge de 1,4 fois est définie, PTRQ est légèrement inférieur à 0,7.

Exemple de réglage)

Function main
  Integer icnt
  Real rtrq(6)

  Motor On
  Power High
'   Power Low
  Weight 2
  Speed 50
  Accel 80, 80

  icnt = 0
  PTCLR
  LimitTorque 100         'init HighPower limit torque
  LimitTorqueLP 100       'init LowPower  limit torque
  CollisionDetect On
  Do
    Call all_ax_move
    Print PTRQ(1), PTRQ(2), PTRQ(3), PTRQ(4), PTRQ(5), PTRQ(6)
    icnt = icnt + 1
    If icnt = 5 Then
      If Power = 1 Then   'High power case
        Print "LimitTorque set"
        rtrq(1) = PTRQ(1) * 1.2 * LimitTorque(1) + 1.0
        rtrq(2) = PTRQ(2) * 1.2 * LimitTorque(2) + 1.0
        rtrq(3) = PTRQ(3) * 1.2 * LimitTorque(3) + 1.0
        rtrq(4) = PTRQ(4) * 1.2 * LimitTorque(4) + 1.0
        rtrq(5) = PTRQ(5) * 1.2 * LimitTorque(5) + 1.0
        rtrq(6) = PTRQ(6) * 1.2 * LimitTorque(6) + 1.0
        Print LimitTorque(1), LimitTorque(2), LimitTorque(3), LimitTorque(4), LimitTorque(5), LimitTorque(6)
        LimitTorque rtrq(1), rtrq(2), rtrq(3), rtrq(4), rtrq(5), rtrq(6)
        Print LimitTorque(1), LimitTorque(2), LimitTorque(3), LimitTorque(4), LimitTorque(5), LimitTorque(6)
        LimitTorqueStop On
      Else               'Low poser case
        Print "LimitTorqueLP set"
        rtrq(1) = PTRQ(1) * 1.4 * LimitTorqueLP(1) + 1.0
        rtrq(2) = PTRQ(2) * 1.4 * LimitTorqueLP(2) + 1.0
        rtrq(3) = PTRQ(3) * 1.4 * LimitTorqueLP(3) + 1.0
        rtrq(4) = PTRQ(4) * 1.4 * LimitTorqueLP(4) + 1.0
        rtrq(5) = PTRQ(5) * 1.4 * LimitTorqueLP(5) + 1.0
        rtrq(6) = PTRQ(6) * 1.4 * LimitTorqueLP(6) + 1.0
        Print LimitTorqueLP(1), LimitTorqueLP(2), LimitTorqueLP(3), LimitTorqueLP(4), LimitTorqueLP(5), LimitTorqueLP(6)
        LimitTorqueLP rtrq(1), rtrq(2), rtrq(3), rtrq(4), rtrq(5), rtrq(6)
        Print LimitTorqueLP(1), LimitTorqueLP(2), LimitTorqueLP(3), LimitTorqueLP(4), LimitTorqueLP(5), LimitTorqueLP(6)
        LimitTorqueStopLP On
      EndIf
    EndIf
    If icnt > 5 Then
      icnt = 6
    Endif
  Loop While icnt > 0

Fend

Function all_ax_move
  Go JA(10, 10, 10, 10, 10, 10)
  Go JA(-10, -10, -10, -10, -10, -10)
Fend