變速輸送帶支援模式 設定校正值與加速度、減速度極限

機器人對傳送帶速度變化產生的跟蹤延遲，將會因傳送帶速度、傳送帶加減速度、使用機器人機種、Inertia設定、Weight設定等而異。

因此，必須依使用環境設定校正值與傳送帶追蹤後的加速度和減速度極限值。此外，要改善機器人的跟蹤延遲，必須調整校正值，並設定適當值。

以Cnv_PosErr函數取得機器人的跟蹤延遲量，並以Cnv_PosErrOffset設定校正值，Cnv_AccelLim設定傳送帶追蹤後的加速度和減速度極限值。

提示

---

調整校正值時，請將Cnv_Fine的設定值設為「0」。若為「0」以外的值，Cnv_PosErr函數將無法取得正確的跟蹤延遲量。

在數量優先模式與準確度優先模式下，無法取得及設定校正值。

關於取得校正值，請確認「準確度優先模式 取得跟蹤延遲」的設定。關於運作程式，請使用後述的範例程式。

關於極限值，請設定為大於停止及運作傳送帶等時的傳送帶加速度、減速度的數值。設定值的標準約為輸送帶加速度、減速度的2倍左右。

過度提高極限時，會因為輸送帶的速度不均與雜訊等使得機器人的動作產生振動。此外，過度調低極限時，即使停止傳送帶，機器人也有可能不會停止追蹤，使得機器人往動作區域外作動。此時請設定追蹤停止線，或使用程式在下游極限停止追蹤。

設定加速度和減速度極限值後，依照以下步驟設定校正值，並取得機器人的跟蹤延遲量。

變更校正值並重複執行數次，以求得適當的校正值。

Integer fileNum                          ' 宣告檔案編號
Function Cnv_PosErr_measure
  Motor On
  Go P0                                  ' 移動至機器人動作開始位置
  Power High
  Speed 100
  Accel 100, 100
  Cnv_Accel 1, 2000
  Cnv_Fine 1,0                           ' Fine設定
  Cnv_Mode 1,2                           ' 變速傳送帶支援模式
  Cnv_PosErrOffset 1,10                  ' 設定校正值
  ' 傳送帶運作檢查
  If Cnv_Speed(1) < 0.1 Then
    Print "傳送帶無運作"
    Exit Function
  EndIf

  ' 將虛擬工件註冊至佇列
  Cnv_QueRemove 1, All                   ' 清除佇列
  Cnv_Trigger (1)                        ' 將傳送帶脈衝閂鎖
  Cnv_QueAdd 1, XY(0, CY(P1@Cnv(1)), CZ(P1@Cnv(1)), CU(P1@Cnv(1)), 0, 0) /CNV(1)
   ' 以P1為基準，將虛擬工件登錄至佇列

  Wait Cnv_QueLen(1, CNV_QUELEN_PICKUPAREA) > 0
  ' 等待直到佇列進入拾取區域內
  Xqt CnvPosErrTest                      ' 在其他任務開始取得校正值

  '執行動作
  Go Cnv_QueGet(1,0)                     ' 為SCARA機器人時
  'Go Cnv_Queget(1,0):U(90):V(0):W(180)  ' 為6軸機器人時

  Do
    Wait 0.02
  Loop Until (CX(RealPos@CNV(1)) >= Cnv_Downstream(1))
  ' 等待直到抵達下游範圍
  Go here                                ' 機器人停止
  Cnv_QueRemove 1, All                   ' 佇列初始化
  Wait 0.5
  Quit CnvPosErrTest                     ' 結束取得校正值
  motor off

Fend

Function CnvPosErrTest
  fileNum = FreeFile                     ' 取得檔案編號
  WOpen "poserr.csv" As #fileNum         ' csv檔案名稱
  Print #fileNum, "Time[sec],Cnv_PosErr[mm],Cnv_Speed[mm/s]"
  TmReset 0
  Do
    Print #fileNum, Tmr(0), ",", Cnv_PosErr(1), ",",
    Cnv_Speed(1)
    Wait 0.01
  Loop
Fend

在Epson RC+ 8.0的專案資料夾中創建「poserr csv」。請在電子表格軟體中開啟檔案，並創建折線圖或散佈圖。

變更校正值並多次取得資料，即可創建如下所示的圖表。

傳送帶跟蹤動作後的Cnv_PosErr函數之回傳值，將為傳送帶跟蹤動作中取得的Cnv_PosErr峰值。在創建圖表時，此峰值相當實用。

若跟蹤延遲為正，表示機器人比工件更過度進入下游範圍。

藉由繪製相對於校正值的機器人跟蹤延遲，即可設定適當的校正值。

請依照上圖的結果，將如下列所示的校正值設定新增至傳送帶跟蹤程式。

Cnv_PosErrOffset 1, 22.7  ' 校正值

注意

---

• 此步驟中使用的校正值是參考值。請注意，根據設定的校正值和執行環境不同，作業可能不會成功，或是動作可能會產生振動。
• 如果機器人動作異常，請立即按下緊急按鈕。