Programme

Si la ligne d'abandon de suivi est configurée, l'erreur 4406 ne se produit pas. Lorsque vous réglez la ligne d'abandon de suivi, utilisez Cnv_Flag dans le programme suivant. N'utilisez pas ce programme lorsque la ligne d'abandon n'est pas utilisée.

POINTS CLÉS

---

• Utilisez le programme 2 après la configuration de la limite aval dans le programme 1 et après que Cnv_Flag n'indique pas 2 et 3.
• Lors de l'utilisation du programme 1, le robot peut fonctionner sans erreur même si le réglage en aval n'est pas adéquat car le robot interrompt le mouvement de suivi. Cependant, l'annulation du suivi augmente le temps de cycle. Il est recommandé d'ajuster la ligne en aval si vous utilisez le programme 1.

Programme 1

Function RB1
  'Se déplace à la position d'attente P0
  Jump P0
  Do
    'Attend jusqu'à ce que la pièce dépasse la limite amont
    Wait Cnv_QueLen(1, CNV_QUELEN_PICKUPAREA) > 0
    Jump Cnv_QueGet(1)          'Exécute la commande pour opérer le suivi de convoyeur

    'Lorsque l'état est normal, effectue la saisie
   If Cnv_Flag(1) = 0 Then
       On Vacuum1               'Aspiration activée
       Wait 0.1

       'Si la pièce passe la ligne d'abandon de suivi durant la saisie, entraînant l'arrêt du suivi,
       la libération de la pièce qui n'a pas pu être saisie.
       If Cnv_Flag(1) = 3 Then
          Jump P2               'Se déplace à la position pour libérer la pièce qui n'a pas pu être saisie
          Off Vacuum1           'Libère la pièce
          Wait 0.1
          Jump P0               'Se déplace à la position d'attente P0

       'La pièce saisie est déplacée sur la position de placement P1
       Else
          Cnv_QueRemove 1, 0    'Supprime la file d'attente saisie
          Jump P1               'Se déplace à la position pour libérer la pièce
          Off Vacuum1           'Libère la pièce
          Wait 0.1
       EndIf


'Si l'opération est annulée car la pièce est susceptible de franchir la ligne d'abandon de suivi, la file d'attente est supprimée.
    ElseIf Cnv_Flag(1) = 1 Then
       Cnv_QueRemove 1, 0       'Supprime les données de la file d'attente


'Si l'opération est annulée car la pièce se trouve en dehors de la zone de saisie au moment de l'exécution ' de la commande d'opération, la file d'attente est supprimée.

    ElseIf Cnv_Flag(1) = 4 Then
       Cnv_QueRemove 1, 0       'Supprime les données de la file d'attente

    'Si le mouvement de suivi est interrompu car la pièce a franchi la ligne d'abandon de suivi,
    'la file d'attente est supprimée.
    ElseIf Cnv_Flag(1) = 2 Then
       Cnv_QueRemove 1, 0       'Supprime les données de la file d'attente
       Jump P0                  'Se déplace à la position d'attente P0
    EndIf
  Loop
Fend

Programme 2

Function RB1

  'Se déplace à la position d'attente P0
  Jump P0
  Do
    'Attend jusqu'à ce que la pièce dépasse la limite amont
    Wait Cnv_QueLen(1, CNV_QUELEN_PICKUPAREA) > 0
    Jump Cnv_QueGet(1)             'Démarre le suivi

'Lorsque l'état est normal, effectue la saisie
    If Cnv_Flag(1) = 0 Then
       On Vacuum1              'Aspiration activée
       Wait 0.1
       Cnv_QueRemove 1, 0    'Supprime la file d'attente saisie
       Jump P1                 'Se déplace à la position pour libérer la pièce
       Off Vacuum1             'Libère la pièce
       Wait 0.1

'Si l'opération est annulée car la pièce est susceptible de franchir la ligne d'abandon de suivi, la file d'attente est supprimée.
ElseIf Cnv_Flag(1) = 1 Then
       Cnv_QueRemove 1, 0       'Supprime les données de la file d'attente

    'Si l'opération est annulée car la pièce se trouve en dehors de la zone de saisie au moment de l'exécution
    'la commande est en dehors de la zone de saisie, la file d'attente est supprimée.
    ElseIf Cnv_Flag(1) = 4 Then
       Cnv_QueRemove 1, 0       'Supprime les données de la file d'attente
    EndIf
  Loop
Fend