可变速传送带支持模式 校正值和加速度、减速度制限値的设置

机器人对传送带速度变化的跟踪延迟，取决于传送带的速度、传送带的加减速度、使用的机器人类型、Inertia设置和Weight设置等因素。

因此，需要根据使用环境设置校正值和传送带追踪后的加速度和减速度的限制值。为了改善机器人的跟踪延迟，需要调整校正值并设置适当的值。

用Cnv_PosErr函数获得机器人跟踪延迟量，用Cnv_PosErrOffset设置校正值，用Cnv_AccelLim设置传送带追踪后的加速度和减速度的限制值。

要点

---

调整校正值时，请将Cnv_Fine设置为“0”。如果该值不为“0”，则用Cnv_PosErr函数无法正确获取跟踪延迟量。

在数量优先模式和精度优先模式中，无法获取和设置校正值。

有关校正值的获取，请确认“精度优先模式 获取跟踪延迟”的设置。设计程序时请参考以下示例。

请将限制值设为大于停止或运转传送带时的加速度、减速度。设置值的大致标准为传送带的加速度、减速度的2倍左右。

如果将限制值提得过高，受传送带速度不均和噪音的影响，机器人的动作将产生振动。如果将限制值降得过低，则即使停止传送带，机器人也会跟踪而不会停止，可能移动到机器人的动作区域之外。在此情况下，请设置放弃跟踪线，或通过在程序中设置，使其在下游范围停止跟踪。

设置加速度和减速度的限制值后，请参考以下步骤设置校正值，获取机器人的跟踪延迟量。

请更改校正值并多次执行，重复验证以获取最佳校正值。

Integer fileNum                          '  声明文件编号
Function Cnv_PosErr_measure
  Motor On
  Go P0                                  ' 移至机器人动作开始位置
  Power High
  Speed 100
  Accel 100, 100
  Cnv_Accel 1, 2000
  Cnv_Fine 1,0                           ' Fine设置
  Cnv_Mode 1,2                           ' 可变速传送带对应模式
  Cnv_PosErrOffset 1,10                  ' 设置校正值
  ' 传送带运行检查
  If Cnv_Speed(1) < 0.1 Then
    Print "传送带未运行"
    Exit Function
  EndIf

  ' 将虚拟工件注册到队列
  Cnv_QueRemove 1, All                   ' 清除队列
  Cnv_Trigger (1)                        ' 锁存传送带脉冲
  Cnv_QueAdd 1, XY(0, CY(P1@Cnv(1)), CZ(P1@Cnv(1)), CU(P1@Cnv(1)), 0, 0) /CNV(1)
   ' 基于P1将虚拟工件注册到队列

  Wait Cnv_QueLen(1, CNV_QUELEN_PICKUPAREA) > 0
  ' 待机至队列进入拾取区域内
  Xqt CnvPosErrTest                      ' 在其他任务中开始获取校正值

  '执行动作
  Go Cnv_QueGet(1,0)                     ' 使用SCARA机器人时
  'Go Cnv_Queget(1,0):U(90):V(0):W(180)  ' 使用6轴机器人时

  Do
    Wait 0.02
  Loop Until (CX(RealPos@CNV(1)) >= Cnv_Downstream(1))
  ' 待机至到达下游范围
  Go here                                ' 机器人停止
  Cnv_QueRemove 1, All                   ' 对队列进行初始化
  Wait 0.5
  Quit CnvPosErrTest                     ' 校正值的获取结束
  motor off

Fend

Function CnvPosErrTest
  fileNum = FreeFile                     ' 获取文件编号
  WOpen "poserr.csv" As #fileNum         ' csv文件名称
  Print #fileNum, "Time[sec],Cnv_PosErr[mm],Cnv_Speed[mm/s]"
  TmReset 0
  Do
    Print #fileNum, Tmr(0), ",", Cnv_PosErr(1), ",",
    Cnv_Speed(1)
    Wait 0.01
  Loop
Fend

在Epson RC+ 8.0的项目文件夹中创建“poserr csv”。在Excel等软件打开文件，创建线形图或散点图。

更改校正值并多次获取数据，即可创建以下图表。

传送带跟踪动作后的Cnv_PosErr函数的返回值，为传送带跟踪动作期间获取的Cnv_PosErr峰值。创建图表时，使用该峰值将非常方便。

跟踪延迟为正时，表示机器人比工件向下游方向移动的太远。

可相对于校正值，绘制机器人的跟踪延迟，即可设置最适当的校正值。

请根据上图的结果，将以下校正值设置添加到传送带跟踪程序中。

Cnv_PosErrOffset 1, 22.7  ' 校正值

注意

---

• 此步骤中说明的校正值仅作为参考值。根据设置的校正值和工作环境，不一定会设置成功，并可能发生振动。
• 如果机器人发生意外动作，请立即按下紧急停止按钮。